home *** CD-ROM | disk | FTP | other *** search
/ Ham Radio / Ham Radio CD-ROM (Emerald Software) (1995).ISO / ant / antenna2 / lpda.bas < prev    next >
BASIC Source File  |  1986-08-10  |  1KB  |  46 lines
  1. 10 CLS
  2. 20 REM   5/20/86
  3. 30 T$="LOG PERIODIC DIPOLE ARRAY DESIGN":L=1:GOSUB 450
  4. 40 REM   AHMAD FAIZAL MOHD ZAIN
  5. 50 DIM L(200)
  6. 60 :
  7. 70 PRINT:PRINT:PRINT
  8. 80 INPUT"ENTER MINIMUM FREQUENCY (MHz) ";FMIN
  9. 90 INPUT"ENTER MAXIMUM FREQUENCY (MHz) ";FMAX
  10. 100 INPUT"ENTER SCALE FACTOR (TAU) ";TAU
  11. 110 INPUT"ENTER SPACING FACTOR (SIGMA) ";SIGMA
  12. 120 :
  13. 130 ALPHA=(360/3.141592)*ATN((1-TAU)/(4*SIGMA))     'ANGLE OF VERTEX
  14. 140 N=INT(LOG(FMIN/FMAX)/LOG(TAU)+2!)              'NUMBER OF ELEMENTS
  15. 150 LAMBDAMAX=300/FMIN
  16. 160 :
  17. 170 PRINT:PRINT
  18. 180 PRINT"NUMBER OF ELEMENTS NEEDED ";N
  19. 190 PRINT USING "ANGLE OF VERTEX = ##.##";ALPHA;:PRINT" DEGREES"
  20. 200 PRINT: PRINT"THE ELEMENTS ARE":PRINT
  21. 210 L(1)=LAMBDAMAX/2:I=1:GOSUB 370
  22. 220 :
  23. 230 FOR I=2 TO N
  24. 240   L(I)=TAU*L(I-1)
  25. 250  SPACING=2*SIGMA*L(I)
  26. 260   GOSUB 370
  27. 270 NEXT
  28. 280 :
  29. 290 XMAX=L(1)/(2*TAN(ALPHA*3.141592/180))
  30. 300 XMIN=L(N)/(2*TAN(ALPHA*3.141592/180))
  31. 310 X=XMAX-XMIN
  32. 320 PRINT
  33. 330 PRINT"LENGTH OF ARRAY = ";X;" METERS"
  34. 340 PRINT:PRINT
  35. 350 :
  36. 360 GOTO 390
  37. 370 PRINT "LENGTH (";I;:PRINT USING ") = ##.###";L(I);:PRINT USING "     SPACING = ##.###";SPACING
  38. 380 RETURN
  39. 390 T$="DO YOU WANT TO RUN THIS PROGRAM AGAIN (Y/N)? ":L=23:COLOR 20,0:GOSUB 450:COLOR 7,0
  40. 400 AN$=INKEY$
  41. 410 IF AN$="Y" OR AN$="y" THEN RUN
  42. 420 IF AN$="N" OR AN$="n" THEN END
  43. 430 GOTO 390
  44. 440 :
  45. 450 LOCATE L,(80-LEN(T$))/2+1:PRINT T$:RETURN    'SUBROUTINE TO CENTRE TEXT
  46.